一直不满意短线宝只能查看当日数据，趁假期写了个历史"短线宝"；目前除了最后封板时间与开板时间没有（官方未提供），其他数据已别无二致。
若无超一年以上的复盘需求，排序时尽量选择较少的数据个数(本人仅用125个)，能提升指标排序的加载速度。
另外"文本类型的最大输出汉字数"须设置为9。
Z1:=IF(INBLOCK('科创板') OR INBLOCK('创业板'),0.2,IF(INBLOCK('北证A股'),0.3,IF(INBLOCK('ST板块') OR NAMELIKE('S') AND INBLOCK('ST板块')=0,0.05,0.1)));
ZTJ:=ZTPRICE(REF(CLOSE,1),Z1);
DTJ:=DTPRICE(REF(CLOSE,1),Z1);
FDE:=GPJYVALUE(24,2,0);{封单额}
ZT:=ZTJ=C AND FDE>0 AND AMO>0;{涨停}
ZB1:=ZTJ=H AND C<ZTJ AND GPJYVALUE(24,2,0)>0;
ZB2:=C=ZTJ AND FDE=0;
ZB:=ZB1 OR ZB2;{炸板}
CJZT:=ZT OR ZB;
{次日表现}
ZF:=(REFX(C,1)/C-1)*100;{收盘}
KP:=(REFX(O,1)/C-1)*100;{开盘}
ZD:=(REFX(L,1)/C-1)*100;{最低}
ZG:=(REFX(H,1)/C-1)*100;{最高}
{流通市值Z}
LTP:=FINANCE(46)/10000;
JE1:=IF(LTP<10000,LTP,LTP/10000);
DX1:=LTP<10000;
DX2:=LTP>10000 AND LTP<100000;
DX3:=LTP>100000 AND LTP<1000000;
DX4:=LTP>1000000 AND LTP<10000000;
DX5:=LTP>10000000;
JE2:=IF(DX1 OR DX4 OR DX5,VAR2STR(JE1,0),IF(DX2,VAR2STR(JE1,2),VAR2STR(JE1,1)));
DW:=IF(LTP<10000,'万','亿');
LTZ:=STRCAT(JE2,DW);
{涨停时间}
R0:=GPJYVALUE(24,1,1);
V1:=INTPART(R0/10000);
S:=IF(V1=9,VARCAT('0',VAR2STR(V1,0)),VAR2STR(V1,0));{时}
R1:=R0-V1*10000;
V2:=INTPART(R1/100);
F:=IF(V2=0,'00',IF(V2>0 AND V2<10,VARCAT('0',VAR2STR(V2,0)),VAR2STR(V2,0)));{分}
V3:=IF(R1>=100,R1-V2*100,DRAWNULL);
V4:=IF(V3<10,VARCAT('0',VAR2STR(V3,0)),VAR2STR(V3,0));
M:=IF(R1=0,'00',IF(R1>0 AND R1<10,VARCAT('0',VAR2STR(R1,0)),IF(R1>=10 AND R1<100,VAR2STR(R1,0),V4)));{秒}
ZTSJ:=VARCAT(VARCAT(VARCAT(VARCAT('',S),':'),F),VARCAT(':',M));
{开板数}
K0:=GPJYVALUE(14,2,1);
K1:=VAR2STR(K0,0);
SS:=IF(K0<10,' ',' ');
KBS:=VARCAT(SS,VARCAT(K1,'次'));
{换手Z}
HSL:=V*100/FINANCE(46)*100;
RX:=VAR2STR(HSL,2);
CD1:=LTP>=10000 AND LTP<100000 AND HSL>=10;
CD2:=LTP>=10000 AND LTP<100000 AND HSL>0 AND HSL<10;
CD3:=LTP<10000 AND HSL>0 AND HSL<10;
CD4:=LTP<10000 AND HSL>10;
CD5:=LTP>=100000 AND LTP<1000000 AND HSL>=10;
CD6:=LTP>=100000 AND LTP<1000000 AND HSL>0 AND HSL<10;
CD7:=LTP>=1000000 AND LTP<10000000 AND HSL>0 AND HSL<10;
HKG:=IF(CD1,' ',IF(CD2 OR CD6,' ',IF(CD3,' ',IF(CD4,' ',IF(CD5,' ',IF(CD7,' ',' '))))));
HSZ:=VARCAT(HKG,RX);
{细分行业}
HY:=STRLEN(MOREHYBLOCK);
TQ:=IF(HY=4,' ',IF(HY=6,' ',IF(HY=2,' ',' ')));
XFHY:=STRCAT(MOREHYBLOCK,TQ);
{地区}
DQ:=SUBSTR(DYBLOCK,1,4);
{板型}
YZB:=O=ZTJ AND L=ZTJ AND ZT;
TZB:=O=ZTJ AND L<ZTJ AND ZT;
HSB:=O<ZTJ AND ZT;
DTB:=L=DTJ AND ZT;
YKB:=ZB AND C>=REF(C,1);
KFL:=ZB AND C<REF(C,1) AND C<>DTJ;
TDB:=ZB AND C=DTJ;
LX:=IF(YZB,'一字板',IF(TZB,'T字板',IF(HSB,'换手板',IF(DTB,'地天板',IF(KFL,'开翻绿',IF(TDB,'天地板',IF(YKB,'已开板','')))))));{类型}
{几天几板}
SC:=EXISTR(ZT,3,1)=0 AND ZT;
D:=BARSLAST(SC)+1;
N:=COUNT(ZT,D);
JT:=IF(EXISTR(ZT,3,0),VARCAT(VAR2STR(D,0),'天'),'');{几天}
JB:=IF(EXISTR(ZT,3,0),VARCAT(VAR2STR(N,0),'板'),'');{几板}
SB:=D=1 AND N=1;{首板}
LB1:=D=N AND N>1 AND N<10;{>=2连板，<10连板}
LB2:=D=N AND N>=10;{>=10连板}
QT1:=D<10 AND N<10 AND EXISTR(ZT,3,0) AND D>N;
QT2:=D>=10 AND N<10 AND EXISTR(ZT,3,0);
KG1:=IF(SB AND TZB=0,' ',IF(EXISTR(ZT,3,0)=0,' ',' '));
KG2:=IF(LB1 AND TZB=0,' ',IF(LB2 AND TZB=0,' ',' '));
KG3:=IF(QT1 OR YKB AND TZB=0,' ',IF(QT2 OR YKB AND TZB=0,' ',IF(QT1 AND TZB,' ',IF(QT2 AND TZB,' ',' '))));
JH:=IF(SB,VARCAT(KG1,'首板'),IF(LB1 OR LB2,VARCAT(KG2,VARCAT(VAR2STR(D,0),'连板')),IF(EXISTR(ZT,3,0)=0,VARCAT(KG1,'--'),VARCAT(KG3,VARCAT(JT,JB)))));
{输出}{延进公式网 www.6073168.com}
涨幅%:=IF(CJZT,(C/REF(C,1)-1)*100,DRAWNULL);
涨停时间 开板:DRAWTEXT(CJZT,0,VARCAT(ZTSJ,KBS));
类型 几天几板:DRAWTEXT(CJZT,0,VARCAT(LX,JH));
连板数:IF(CJZT,BARSLASTCOUNT(ZT),DRAWNULL);
次日%:IF(CJZT,ZF,DRAWNULL);
开盘%:IF(CJZT,KP,DRAWNULL);
最低%:IF(CJZT,ZD,DRAWNULL);
最高%:IF(CJZT,ZG,DRAWNULL);
流通Z 换手Z%:DRAWTEXT(CJZT,0,VARCAT(LTZ,HSZ));
细分行业 地区:DRAWTEXT(CJZT,0,STRCAT(XFHY,DQ));
{时间排序}
SJ:IF(CJZT,GPJYVALUE(24,1,0)/10000,DRAWNULL);
